import? 'xcode.just'
import? 'environment.just'

target := 'Sora'
identifier := "me.fuwn." + target
derived_data := "/Users/${USER}/Library/Developer/Xcode/DerivedData"
location := "/Users/${USER}/Applications"

alias fmt := format
alias b := build
alias gen := generate

fetch:
   curl https://raw.githubusercontent.com/Fuwn/justfiles/refs/heads/main/xcode.just > xcode.just

format:
	just _format {{target}}

build destination="platform=macOS":
  command -v xcbeautify >/dev/null 2>&1 \
    && xcodebuild -configuration Release -scheme {{target}} -destination '{{destination}}' build | xcbeautify \
    || just _build {{target}}

build_ios:
  just build "platform=iOS,arch=arm64,name={{device_name}}"

run:
	just _open {{target}}

install derived_data=derived_data location=location:
  cp -r {{derived_data}}/{{target}}-*/Build/Products/Release/{{target}}.app {{location}}

generate:
  mint run xcodegen@synced_folder generate

install_ios derived_data=derived_data:
  xcrun devicectl device install app --device {{device_identifier}} {{derived_data}}/{{target}}-*/Build/Products/Release-iphoneos/{{target}}.app

run_ios:
  xcrun devicectl device process launch --device {{device_identifier}} {{identifier}}

ios:
  just build_ios
  just install_ios
  just run_ios

macos:
  just build
  just run