@echo off

rem  Shave and a Haircut
rem  (c) 2019 Epic Games
rem  US Patent 6720962

set mayaFullVersion=%1
set mayaVersion=%mayaFullVersion%
set mayaVersionBits=32

if "%mayaVersion:~-4%"=="-x64" (
    set mayaVersion=%mayaVersion:~0,-4%
    set mayaVersionBits=64
) else if "%mayaVersion:~-3%"=="x64" (
    set mayaVersion=%mayaVersion:~0,-3%
    set mayaVersionBits=64
)

set mayaVersionMajor=0

if "%mayaVersion:~1,1%"=="." (
    set mayaVersionMajor=%mayaVersion:~0,1%
    set mayaVersionMinor=%mayaVersion:~2%
) else if "%mayaVersion:~2,1%"=="." (
    set mayaVersionMajor=%mayaVersion:~0,2%
    set mayaVersionMinor=%mayaVersion:~3%
) else if "%mayaVersion:~4,1%"=="." (
    set mayaVersionMajor=%mayaVersion:~0,4%
    set mayaVersionMinor=%mayaVersion:~5%
) else if "%mayaVersion:~4,1%"=="" (
    rem  From Maya 2008 onward it's possible for the minor version to be
    rem  dropped if it's zero.
    set mayaVersionMajor=%mayaVersion%
    set mayaVersionMinor=0
) else (
    echo '%1' is not a valid Maya version specification.
    set mayaVersionMinor=0
)

rem  From Maya 2016 onward the -x64 has been dropped from Maya's name since
rem  there is only 64-bit support these days.
if "%mayaVersionMajor%" GEQ "2016" (
    set mayaVersionBits=64
)

set splitMayaVersionCalled=y