@echo off

rem  Shave and a Haircut
rem  (c) 2019 Epic Games
rem  US Patent 6720962

rem  This script extracts the current Shave version string from the
rem  shaveVersion.mel script file and place it into the 'shaveVersion'
rem  environment variable.

rem  We need the shaveVersion.mel script so let's make sure it exists.

if not exist scripts\shaveVersion.mel goto noFile
    find "return" <scripts\shaveVersion.mel > version.dat
    set /p shaveVersion=<version.dat
    del version.dat

    rem
    rem  Note that because of the recursive nature of these assignments
    rem  (i.e. shaveVersion is being defined in terms of shaveVersion)
    rem  they will not work inside an 'if cond (...) else (...)' construct
    rem  because Windows treats that as a single statement and does variable
    rem  substitution once, when the statement is read in, not as each
    rem  statement is executed. So we have to use the 'if cond goto' construct
    rem  instead.
    rem
    set shaveVersion=%shaveVersion:return=%
    set shaveVersion=%shaveVersion:"=%
    set shaveVersion=%shaveVersion:;=%
    set shaveVersion=%shaveVersion: =%
    set shaveVersion=%shaveVersion:	=%

    set result=0

goto done
:noFile
    echo Error: cannot find scripts\shaveVersion.mel.  Build terminated.
    set result=1
:done