@echo off

rem  Shave and a Haircut
rem  (c) 2019 Epic Games
rem  US Patent 6720962

set result=0
setlocal

if "%~1"=="" (
    echo No maya version provided.
    goto error
)

if not defined SHAVE_RMAN_SDKS (
    echo SHAVE_RMAN_SDKS not defined. Shave will be built without RenderMan support.
    goto error
)

call ..\utils\splitMayaVersion %1
set mayaCompactVersion=%mayaVersionMajor%%mayaVersionMinor%
call ..\utils\getVSVersion

if %vsVersion%==vs11 (
    call "%VS110COMNTOOLS%\..\..\VC\bin\x86_amd64\vcvarsx86_amd64.bat"
) else if %vsVersion%==vs14 (
    call "%VS140COMNTOOLS%\..\..\VC\bin\x86_amd64\vcvarsx86_amd64.bat"
) else (
    goto error
)

rem  Find all the ranges of RenderMan which we support for this version of
rem  Maya and build the plugins for them.
rem
cd plugins\shaveHairBxdf\shaveHairBxdf-%vsVersion%

for /f "tokens=1,*" %%i in ('findstr "^%mayaVersion%:" ..\..\..\supportedRManVersions.txt') do call :buildRange %%j
if errorlevel 1 goto error
goto done

rem -----------------------------------------------------------------------

:buildRange

set minVer=%1
set maxVer=%2
set buildVer=%3

set versionTag=%buildVer:~0,2%

call ..\..\..\..\utils\vcbuild.bat . shaveHairBxdf RelM%mayaVersion%R%versionTag% %vsVersion% shaveHairBxdf 64
if not %result%==0 exit /b 1
exit /b

rem -----------------------------------------------------------------------

:error
endlocal
set result=1
goto :eof

:done
endlocal